6502-OS/system/keypad.s65

;********************************************************************************
; @module keypad4x4
; @type driver
; @device 4x4 Matrix Keypad
; @details
;   The LCD must be connected to a W65C22N Interface Chip:
;     - IO.RB0-7  -> 
; @requires KP_IO: Base Address of IO Chip
; @depends IO-W65C22N 
;********************************************************************************


.ifndef INCLUDE_KEYPAD
INCLUDE_KEYPAD = 1
.ifndef KP_IO
    .fatal "KP_IO is not defined: set it to the base address of the IO chip of the Keypad"
.endif


RBUF_MEM_START = $200
RBUF_MEM_END = $2ff
.define RBUF_NAME "keypad"
.include "buffer.s65"

KB_VAR      = $05
KB_LAST     = $06

.proc kp_init
    ; todo remove
    stz KB_LAST
    ; todo remove later
    lda #$ff
    sta KP_IO+IO_DDRB
    stz KP_IO+IO_RB

    ; INIT KEYPAD 
    lda #%00001111; KP_IO+IO_RB 0-3 output
    sta KP_IO+IO_DDRB
    stz KP_IO+IO_RB        ; KP_IO+IO_RB 4-7 1 so keypad press can be detected
    stz KP_IO+IO_ACR

    ; lda #%00010000  ; set CB1 to interrupt on pos. edge
    lda #IO_PCR_CB1_IP_AE
    sta KP_IO+IO_PCR
    jsr rb_keypad_init  ; init keybuffer
    lda #%10010000  ; enable interrupt for CB1 on KP_IO
    sta KP_IO+IO_IER
    rts
.endproc

;********************************************************************************
; @function Read which key is pressed on the keypad
; @details
;   Checks which key is pressed and stores it in the keybuffer
;   The value stored in the keybuffer is the offset which must be added to 
;   kp_VALUES to retrieve the key that was pressed
;********************************************************************************
.proc kp_read_on_irq
    ; test each "row" and check which column is 1
    lda #%00001110
    ldx #$00
    jsr @kp_read_column
    lda #%00001101
    ldx #$04
    jsr @kp_read_column
    lda #%00001011
    ldx #$08
    jsr @kp_read_column
    lda #%00000111
    ldx #$0c
    jsr @kp_read_column
    bra @kp_read_rts
@kp_read_column:
    sta KP_IO+IO_RB
    lda KP_IO+IO_RB
    sta KB_VAR  ; store result in zeropage so that bbr can be used
    bbr4 KB_VAR,@kp_write
    inx
    bbr5 KB_VAR,@kp_write
    inx
    bbr6 KB_VAR,@kp_write
    inx
    bbr7 KB_VAR,@kp_write
    rts
@kp_write:
    ; temporary: store last keypress in KB_LAST, TODO: remove
    lda kp_VALUES,x
    sta KB_LAST
    txa
    jsr rb_keypad_write
@kp_read_rts:
    stz KP_IO+IO_RB
    ; lda KP_IO+IO_RB  ; read to definetly clear the interrupt flag
    rts
.endproc

.segment "RODATA"
kp_VALUES:
    ; TODO change to literal
    .byte "123A", "456B", "789C", "*0#D" 
.endif